mirror of
https://github.com/fish-shell/fish-shell.git
synced 2026-04-26 05:01:15 -03:00
bd5232e0e2
25d83ed0d7 (included in 3.0.0) added a `string` check that
did not use `--`, so negative numbers were interpreted as options.
Apparently nobody is using this.
(Again, this is for the `seq` fallback used on OpenBSD)
57 lines
1.4 KiB
Fish
57 lines
1.4 KiB
Fish
# If seq is not installed, then define a function that invokes __fish_fallback_seq
|
|
# We can't call type here because that also calls seq
|
|
|
|
if not command -sq seq
|
|
# No seq command
|
|
function seq --description "Print sequences of numbers"
|
|
__fish_fallback_seq $argv
|
|
end
|
|
|
|
function __fish_fallback_seq --description "Fallback implementation of the seq command"
|
|
|
|
set -l from 1
|
|
set -l step 1
|
|
set -l to 1
|
|
|
|
switch (count $argv)
|
|
case 1
|
|
set to $argv[1]
|
|
|
|
case 2
|
|
set from $argv[1]
|
|
set to $argv[2]
|
|
|
|
case 3
|
|
set from $argv[1]
|
|
set step $argv[2]
|
|
set to $argv[3]
|
|
|
|
case '*'
|
|
printf (_ "%s: Expected 1, 2 or 3 arguments, got %d\n") seq (count $argv)
|
|
return 1
|
|
|
|
end
|
|
|
|
for i in $from $step $to
|
|
if not string match -rq -- '^-?[0-9]*([0-9]*|\.[0-9]+)$' $i
|
|
printf (_ "%s: '%s' is not a number\n") seq $i
|
|
return 1
|
|
end
|
|
end
|
|
|
|
if test $step -ge 0
|
|
set -l i $from
|
|
while test $i -le $to
|
|
echo $i
|
|
set i (math -- $i + $step)
|
|
end
|
|
else
|
|
set -l i $from
|
|
while test $i -ge $to
|
|
echo $i
|
|
set i (math -- $i + $step)
|
|
end
|
|
end
|
|
end
|
|
end
|