mirror of
https://github.com/fish-shell/fish-shell.git
synced 2026-04-25 20:41:15 -03:00
d835c5252a
The overwhelming majority of localizable messages comes from
completions:
$ ls share/completions/ | wc -l
$ 1048
OTOH functions also contribute a small amount, mostly via their
descriptions (so usually just one per file).
$ ls share/functions/ | wc -l
$ 237
Most of these are private and almost never shown to the user, so it's
not worth bothering translators with them. So:
- Skip private (see the parent commit) and deprecated functions.
- Skip wrapper functions like grep (where the translation seems to
be provided by apropos), and even the English description is not
helpful.
- Assume that most real systems have "seq", "realpath" etc.,
so it's no use providing our own translations for our fallbacks.
- Mark fish's own functions as tier1, and some barely-used functiosn
and completions as tier3, so we can order them that way in
po/*.po. Most translators should only look at tier1 and tier2.
In future we could disable localization for tier3.
See the explanation at the bottom of
tests/checks/message-localization-tier-is-declared.fish
Part of #11833
53 lines
1.7 KiB
Fish
53 lines
1.7 KiB
Fish
# localization: tier1
|
|
function prompt_pwd --description 'short CWD for the prompt'
|
|
set -l options h/help d/dir-length= D/full-length-dirs=
|
|
argparse -n prompt_pwd $options -- $argv
|
|
or return
|
|
|
|
if set -q _flag_help
|
|
__fish_print_help prompt_pwd
|
|
return 0
|
|
end
|
|
|
|
set -q argv[1]
|
|
or set argv $PWD
|
|
|
|
set -ql _flag_d
|
|
and set -l fish_prompt_pwd_dir_length $_flag_d
|
|
|
|
set -q fish_prompt_pwd_dir_length
|
|
or set -l fish_prompt_pwd_dir_length 1
|
|
|
|
set -l fulldirs 0
|
|
set -ql _flag_D
|
|
and set -l fish_prompt_pwd_full_dirs $_flag_D
|
|
|
|
set -q fish_prompt_pwd_full_dirs
|
|
or set -l fish_prompt_pwd_full_dirs 1
|
|
|
|
for path in $argv
|
|
# Replace $HOME with "~"
|
|
set -l realhome (string escape --style=regex -- ~)
|
|
set -l tmp (string replace -r '^'"$realhome"'($|/)' '~$1' $path)
|
|
|
|
if test "$fish_prompt_pwd_dir_length" -eq 0
|
|
echo $tmp
|
|
else
|
|
# Shorten to at most $fish_prompt_pwd_dir_length characters per directory
|
|
# with full-length-dirs components left at full length.
|
|
set -l full
|
|
if test $fish_prompt_pwd_full_dirs -gt 0
|
|
set -l all (string split -m (math $fish_prompt_pwd_full_dirs - 1) -r / $tmp)
|
|
set tmp $all[1]
|
|
set full $all[2..]
|
|
else if test $fish_prompt_pwd_full_dirs -eq 0
|
|
# 0 means not even the last component is kept
|
|
string replace -ar '(\.?[^/]{'"$fish_prompt_pwd_dir_length"'})[^/]*' '$1' $tmp
|
|
continue
|
|
end
|
|
|
|
string join / -- (string replace -ar -- '(\.?[^/]{'"$fish_prompt_pwd_dir_length"'})[^/]*/' '$1/' $tmp) $full
|
|
end
|
|
end
|
|
end
|