mirror of
https://github.com/fish-shell/fish-shell.git
synced 2026-04-21 00:31:15 -03:00
5e658bf4e9
Things that are not currently happening in this workflow: - No GPG-signature on the Git tag - No *.asc signature file for the tarball (or for any other release assets) - No GPG-signed Debian and other OBS packages To-do: - remove the corresponding entries from https://github.com/fish-shell/fish-shell/wiki/Release-checklist and link to this workflow. - Maybe add some testing (for the Linux packages)?. - Let's hope that this doesn't cause security issues. Usage: 1. run "build_tools/release.sh $version"; this will create and push a tag, which kicks off .github/workflows/release.yml 2. wait for the draft release to be created at https://github.com/fish-shell/fish-shell/releases/tags/$version 3. publish the draft (manually, for now). This should unblock the last part of the workflow (website updates). Closes #10449 Incremental usage example: version=4.0.3 repository_owner=fish-shell remote=origin cd ../fish-shell-secondary-worktree git tag -d $version ||: git push $remote :$version ||: git reset --hard origin/Integration_$version for d in .github build_tools; do { rm -rf $d cp -r ../fish-shell/$d . git add $d } done git commit -m 'Backport CI/CD' echo "See https://github.com/$repository_owner/fish-shell/actions" echo "See the draft release at https://github.com/$repository_owner/fish-shell/releases/$version" ../fish-shell/build_tools/release.sh $version $repository_owner $remote
69 lines
2.4 KiB
CMake
69 lines
2.4 KiB
CMake
# This is Mac-only.
|
|
if (NOT APPLE)
|
|
return()
|
|
endif (NOT APPLE)
|
|
|
|
# The source tree containing certain macOS resources.
|
|
set(OSX_DIR ${CMAKE_CURRENT_SOURCE_DIR}/osx)
|
|
|
|
# 10.9 is the minimum supported version.
|
|
set(CMAKE_OSX_DEPLOYMENT_TARGET "10.9")
|
|
|
|
set(RESOURCE_FILES
|
|
${OSX_DIR}/launch_fish.scpt
|
|
${OSX_DIR}/fish_term_icon.icns
|
|
${CMAKE_CURRENT_SOURCE_DIR}/build_tools/osx_package_scripts/add-shell
|
|
${OSX_DIR}/install.sh
|
|
)
|
|
|
|
# Resource files must be present in the source list.
|
|
add_executable(fish_macapp EXCLUDE_FROM_ALL
|
|
${OSX_DIR}/osx_fish_launcher.m
|
|
${RESOURCE_FILES}
|
|
)
|
|
|
|
# Compute the version. Note this is done at generation time, not build time,
|
|
# so cmake must be re-run after version changes for the app to be updated. But
|
|
# generally this will be run by make_macos_pkg.sh which always re-runs cmake.
|
|
execute_process(
|
|
COMMAND ${CMAKE_CURRENT_SOURCE_DIR}/build_tools/git_version_gen.sh --stdout
|
|
COMMAND cut -d- -f1
|
|
OUTPUT_VARIABLE FISH_SHORT_VERSION
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE)
|
|
|
|
|
|
# Note CMake appends .app, so the real output name will be fish.app.
|
|
# This target does not include the 'base' resource.
|
|
set_target_properties(fish_macapp PROPERTIES OUTPUT_NAME "fish")
|
|
|
|
find_library(FOUNDATION_LIB Foundation)
|
|
target_link_libraries(fish_macapp ${FOUNDATION_LIB})
|
|
|
|
set_target_properties(fish_macapp PROPERTIES
|
|
MACOSX_BUNDLE TRUE
|
|
MACOSX_BUNDLE_INFO_PLIST ${OSX_DIR}/CMakeMacAppInfo.plist.in
|
|
MACOSX_BUNDLE_GUI_IDENTIFIER "com.ridiculousfish.fish-shell"
|
|
MACOSX_BUNDLE_SHORT_VERSION_STRING ${FISH_SHORT_VERSION}
|
|
RESOURCE "${RESOURCE_FILES}"
|
|
)
|
|
|
|
# The fish Mac app contains a fish installation inside the package.
|
|
# Here is where it gets built.
|
|
# Copy into the fish mac app after.
|
|
set(MACAPP_FISH_BUILDROOT ${CMAKE_CURRENT_BINARY_DIR}/macapp_buildroot/base)
|
|
|
|
add_custom_command(TARGET fish_macapp POST_BUILD
|
|
COMMAND ${CMAKE_COMMAND} -E make_directory ${MACAPP_FISH_BUILDROOT}
|
|
COMMAND DESTDIR=${MACAPP_FISH_BUILDROOT} ${CMAKE_COMMAND}
|
|
--build ${CMAKE_CURRENT_BINARY_DIR} --target install
|
|
COMMAND ${CMAKE_COMMAND} -E copy_directory ${MACAPP_FISH_BUILDROOT}/..
|
|
$<TARGET_BUNDLE_CONTENT_DIR:fish_macapp>/Resources/
|
|
VERBATIM
|
|
)
|
|
|
|
# The entitlements file.
|
|
set(MACAPP_ENTITLEMENTS "${CMAKE_SOURCE_DIR}/osx/MacApp.entitlements")
|
|
|
|
# Group our targets in a folder.
|
|
set_property(TARGET fish_macapp PROPERTY FOLDER macapp)
|