\section abbr abbr - manage fish abbreviations

\subsection abbr-synopsis Synopsis
\fish{synopsis}
abbr --add word phrase...
abbr --rename word new_word
abbr --show
abbr --list
abbr --erase word
\endfish

\subsection abbr-description Description

`abbr` manipulates the list of abbreviations that fish will expand.

Abbreviations are user-defined character sequences or words that are replaced with longer phrases after they are entered. For example, a frequently-run command such as `git checkout` can be abbreviated to `gco`. After entering `gco` and pressing @key{Space} or @key{Enter}, the full text `git checkout` will appear in the command line.

Abbreviations are stored in a variable named `fish_user_abbreviations`. This is automatically created as a universal variable the first time an abbreviation is created. If you want your abbreviations to be private to a particular fish session you can put the following in your *~/.config/fish/config.fish* file before you define your first abbrevation:

\fish
if status --is-interactive
    set -g fish_user_abbreviations
    abbr --add first 'echo my first abbreviation'
    abbr --add second 'echo my second abbreviation'
    # etcetera
end
\endfish

You can create abbreviations directly on the command line and they will be saved automatically and made visible to other fish sessions if `fish_user_abbreviations` is a universal variable. If you keep the variable as universal, `abbr --add` statements in <a href="tutorial.html#tut_startup">config.fish</a> will do nothing but slow down startup slightly.

\subsection abbr-options Options

The following parameters are available:

- `-a WORD PHRASE` or `--add WORD PHRASE` Adds a new abbreviation, causing WORD to be expanded to PHRASE.

- `-r WORD NEW_WORD` or `--rename WORD NEW_WORD` Renames an abbreviation, from WORD to NEW_WORD.

- `-s` or `--show` Show all abbreviated words and their expanded phrases in a manner suitable for export and import.

- `-l` or `--list` Lists all abbreviated words.

- `-e WORD` or `--erase WORD` Erase the abbreviation WORD.

Note: fish version 2.1 supported `-a WORD=PHRASE`. This syntax is now deprecated but will still be converted.

\subsection abbr-example Examples

\fish
abbr -a gco git checkout
\endfish
Add a new abbreviation where `gco` will be replaced with `git checkout`.

\fish
abbr -r gco gch
\endfish
Renames an existing abbreviation from `gco` to `gch`.

\fish
abbr -e gco
\endfish
Erase the `gco` abbreviation.

\fish
ssh another_host abbr -s | source
\endfish
Import the abbreviations defined on another_host over SSH.
